///////// 文　ゴーストテンプレート
///////// ランダムトーク辞書
///////// written by umeici.

//**** トランスレータ *******************************************************************

//---- OnTranslateイベント --------------------------------------------------------------
//     もっとも単純な例。語尾変え（「。」→「にゅ。」）。動かないようにコメントアウトしています。
//OnTranslate
//{
//	REPLACE(reference0, "。", "にゅ。")
//}

//**** ランダムトーク *******************************************************************

//---- OnAiTalkイベント -----------------------------------------------------------------
OnAiTalk
{
	if mikireflag == 0
	{
		//---- 通常のランダムトーク、ただしチェイン中はチェイントーク
		if CHAIN.IDName == "" {
			RandomTalk
		}
		else {
			ChainTalk
		}
	}
	else
	{
		//---- 見切れ中なので見切れ中のトークを行う
		MikireTalk
	}
}

/*---------------------------------------------------------------------
	かんたん文スクリプト「あやりりす」
	こぴぺするならここから……
	元あったRandomTalkは消すこと
---------------------------------------------------------------------*/
RandomTalk
{
	//高速ランダムトーク処理用
	TOSTR(EVAL(CHR(0x22)+RandomTalkEx()+CHR(0x22)))
}

GetSeasonSlot
{
	//3-5,6-8,9-11,12-2……でいいよね？
	_m = month
	if _m >= 3 && _m <= 5 { '春' }
	elseif _m >= 6 && _m <= 8 { '夏' }
	elseif _m >= 9 && _m <= 11 { '秋' }
	else { '冬' }
}

GetDaySlot
{
	//10日,20日で区切りにしてみた
	_d = day
	if _d <= 10 { '上旬' }
	elseif _d <= 20 { '中旬' }
	else { '下旬' }
}

GetTimeSlotList
{
	//おおざっぱに時間判定
	//このへんは適当に書き換えるとよい。12時のところは「昼飯」にするとか。
	switch hour {
		'深夜' //0時
		'深夜' //1時
		'深夜' //2時
		'深夜' //3時
		'深夜' //4時
		'朝' //5時
		'朝' //6時
		'朝' //7時
		'朝' //8時
		'昼' //9時
		'昼' //10時
		'昼' //11時
		'昼' //12時
		'昼' //13時
		'昼' //14時
		'昼' //15時
		'夕' //16時
		'夕' //17時
		'夕' //18時
		'夜' //19時
		'夜' //20時
		'夜' //21時
		'夜' //22時
		'深夜' //23時
	}
}

GetDOWSlot
{
	//曜日
	switch GETTIME[3] {
		'日'
		'月'
		'火'
		'水'
		'木'
		'金'
		'土'
	}
}

RandomTalkEval
{
	//処理用！さわるな！！
	_fname = 'ランダムトーク' + _argv[0]
	if ISFUNC(_fname) {
		EVAL(_fname)
	}
	else {
		IARRAY
	}
}

RandomTalkEx : nonoverlap
{
	/*=====かきかたの例============================
	ランダムトーク3月 : array
	{
		'ごにょごにょ'
	}
	
	1.かならず最後に : array とつけること！
	2.' 'でトークをかこむこと！ " " じゃないよ！
	=============================================*/
	
	//ランダムトーク朝,昼,夕,夜,深夜etc...
	parallel RandomTalkEval(GetTimeSlotList)
	//ランダムトーク春,夏,秋,冬
	parallel RandomTalkEval(GetSeasonSlot)
	//ランダムトーク?月
	parallel RandomTalkEval("%(month)月")
	//ランダムトーク?月?日
	parallel RandomTalkEval("%(month)月%(day)日")
	//ランダムトーク?月上旬,中旬,下旬
	parallel RandomTalkEval("%(month)月%(GetDaySlot)")
	//ランダムトーク日曜,月曜...
	parallel RandomTalkEval("%(GetDOWSlot)曜")
	//そしてこれがふつう
	parallel ランダムトーク通常
}

/*---------------------------------------------------------------------
	こぴぺするならここまで
---------------------------------------------------------------------*/

ランダムトーク通常 : array
{
	'\u\s[10]\h\s[0]北島。\w9先週出た宿題終わった？\w9\w9\uああ、\w5もうとっくに終わって提出したよ。\w9\w9\h\s[7]\n\n[half]なんであたしが写す前に提出すんのよ、\w5バカ！\w9\w9\u\s[17]\n\n[half]なんで写させてやらなきゃいけないんだ、\w5バカ！\e'
	'\h\s[0]\u\s[10]井上、\w5先週貸したノートはどうした？\w9\w9\h…\w5…\w9\w9\w9\s[3]そういやどうしたっけ？\w9\w9\u\s[12]\n\n[half]ま、\w5待てよオイ。\w9\n明日には提出しなきゃいけないんだぞ。\w9\w9\h\s[20]\n\n[half]あ、\w5それだ、\w5それ。\w9\w9\s[5]そうだ、\w5提出したんだった。\w9\w9\u\s[14]\n\n[half]ふう、\w5おどかすなよ。\w9\w9\h\s[0]\n\n[half]名前はあたしのに書き換えといたけどね。\w9\w9\u\s[19]\n\n[half]…\w5…\w9じょ、\w5冗談だよな？\w9\w9\h\s[6]\n\n[half]どう思う？\e'
	'\u\s[10]\h\s[0]ねえ、\w5北島。\w9\w9\uあん？\w9\w9\h\s[8]\n\n[half]あんた、\w5%ghostのこと好きでしょ？\w9\w9\u\s[12]\n\n[half]な、\w5なんだそりゃいきなり！\w9\w9\h\s[2]\n\n[half]おー。\w9露骨に怪しい。\w9\w9\u\s[11]\n\n[half]た、\w5ただ驚いただけだ。\e'
	'\u\s[10]\h\s[4]パケ割入れとくんだったな〜。\w9\w9\u\s[13]またパケ死か？\w9いいかげん学習しろよ。\w9\w9\h\s[0]\n\n[half]北島、\w5ケータイ貸して。\w9\w9\u\s[16]\n\n[half]断る。\e'
	'\u\s[10]\h\s[0]ねえ、\w5うにゅう。\w9\w9\u\s[51]なんや、\w5さくら。\w9\w9\s[14]\nって、\w5なんでだよ。\w9\w9\h\s[9]\n\n[half]案外ノリいいね、\w5あんたも。\e'
	'\u\s[10]\h\s[3]昨日、\w5女子の着替え覗いてたの、\w5あんたでしょ？\w9\w9\u\s[12]な、\w5なんでだよ！？\w9\w9\h\s[1]\n\n[half]違うっての？\w9\w9\u\s[13]\n\n[half]当たり前だろ。\w9俺がそんなことするわけないだろ。\w9\w9\h\s[8]\n\n[half]しょうがない、\w5信じてやるか。\w9\w9\u\s[14]\n\n[half]はぁ…\w5…\w9。\w9\w9\h\s[0]\n\n[half]信じてあげるから、\w5たこ焼きおごって。\w9\w9\u\s[17]\n\n[half]なんでそうなる！！！\w9\w9\h\s[3]\n\n[half]…\w5…\w9信じなくていいの？\w9\nクラスのみんなに相談しちゃうよ？\w9\w9\u\s[14]\n\n[half]…\w5…\w9お前、\w5絶対鬼だろ。\e'
	'\u\s[10]\h\s[0]ね、\w5北島ゅう。\w9\w9\u…\w5…\w9なに？\w9\w9\h\s[3]\n\n[half]呼んだんだよ。\w9北島ゅう。\w9\w9\u\s[14]\n\n[half]もう一度言ってみてくれよ。\w9\w9\h\s[7]\n\n[half]だからぁ、\w5きたじまゅう！\w9\w9\u\s[13]\n\n[half]お前、\w5どういう発声器官を持ってるんだ？\w9\w9\h\s[2]\n\n[half]あ、\w5あんた、\w5こんなのも発音できずに、\w5\nこの世界で生きていくつもりだったの？？\w9\w9\u\s[12]\n\n[half]ま、\w5まずいのか！？\e'
	'\u\s[-1]\h\s[6]ツメにハートを書く…\w5…\w9\w9\w9\s[0]そこにばんそうこ。\u\s[10]\w9\w9\h\s[5]\n\n[half]ぺたっと貼って…\w5…\w9\w9\w9\s[2]うお！\w9北島！\w9\w9\u\s[13]どした、\w5怪我でもしたのか？\w9見せてみろよ。\w9\w9\h\s[1]\n\n[half]な、\w5なんでもないっつの。\w9\w9\s[7]\nだいたい、\w5とつぜん湧くんじゃない！\w9\nびっくりするでしょ！\w9\w9\u\s[17]\n\n[half]ボウフラみたいに言うな！\e'
	'\u\s[10]\h\s[3]あたしらさ、\w5ケンカが多すぎじゃない？\w9\w9\u\s[18]ほとんど全部お前が原因だけどな。\w9\w9\h\s[7]\n\n[half]なんだとー！\w9あんただって嫌みじゃん！\e:chain=kenka01'
	'\u\s[10]\h\s[0]ねえ、\w5昨日のアレ、\w5見た？\w9\w9\u\s[13]アレってなんだよ。\w9\w9\h\s[2]\n\n[half]ええー！？\w9見てねーの？\w9ばっかじゃん〜？\w9\w9\u\s[17]\n\n[half]だから、\w5何をだよっ！！\e'
	'\u\s[10]\h\s[3]…\w5…\w9北島、\w5そのポッケの、\w5たばこ？\w9\w9\u\s[12]あ…\w5…\w9\w9\w9\s[13]さっき下駄箱の前で拾ったやつだ。\w9\w9\h\s[6]\n\n[half]ほうほう。\w9\nキミも大人への階段を着実に上っているんだね。\w9\w9\u\s[17]\n\n[half]だからちげーっての！\w9\w9\h\s[8]\n\n[half]口止め料に、\w5なんかおごってもらっちゃおっかな。\w9\w9\u\n\n[half]うぐぐぐ。\e'
	'\u\s[10]\h\s[23]なんつーかさー、\w9\w9\s[26]\n毎日こんなんと顔をつきあわせてると、\w5\nもう何も話すこともなくなるよね。\w9\w9\u\s[39]お\w3た\w3が\w3い\w3さ\w3ま\w3だ。\e'
	'\u\s[10]\h\s[5]北島、\w5これどう？\w9これ。\w9\w9\s[6]\nん。\w9\w9\u\s[13]ん。\w9って、\w5なんだよ？\w9なに言ってんだ？\w9\w9\h\s[1]\n\n[half]…\w5…\w9くちびる。\w9\w9\u\s[10]\n\n[half]え？\w9\w9\h\s[7]\n\n[half]リップ塗ってみたの！\w9バカ！\w9\s[-1]\w9\w9\u\s[11]\n\n[half]んなとこ、\w5見ねーって。\e'
	'\u\s[10]\h\s[0]…\w5…\w9\w9\w9\u\s[11]な、\w5なんだよ。\w9\w9\h\s[8]\n\n[half]目をそらした。\w9\n心にやましいことがあるんだね〜？\w9\w9\u\s[14]\n\n[half]なんでそうなるんだ？\e'
	'\u\s[10]\h\s[7]北島！\w9\n%(username)の観察日誌はどうなってんの！？\w9\w9\u\s[12]あ、\w5いけね。\w9まだやってねーや。\w9\w9\h\s[27]\n\n[half]ホントにだらしないやつだなー。\w9\n昨日もサボってたじゃん。\w9\w9\u\s[17]\n\n[half]昨日はお前の当番だ！！\w9\w9\h\s[9]\n\n[half]へ？\w9そうだっけ？\e'
	'\u\s[10]\h\s[29]北島、\w5これ欲しくない？\w9\w9\uなんだ、\w5それ。\w9\w9\h\s[20]\n\n[half]%ghostの生写真。\w9\w9\u\s[13]\n\n[half]…\w5…\w9盗撮はほどほどにしとけよ。\w9\w9\h\s[21]\n\n[half]堂々と目の前に出て撮ってるもん。\w9\w9\u\s[14]\n\n[half]ああ、\w5恐れ入りました。\e'
	'\h\s[-1]\u\s[13]なんだこれ、\w5落とし物か？\w9\n誰んだろ。\w9\w9\h\s[2]ああーー！！\w9\w9\s[7]\n何ひとのカバンあさってんだよ！\w9\w9\u\s[14]\n\n[half]お前のかよ。\w9\n落とし物だと思ってさ。\w9\w9\s[13]\n\n[half]で、\w5なんだよこの趣味の悪い%(bag)は。\w9\w9\h\s[27]\n\n[half]なにがだよー！\w9かわいいじゃん。\e'
	'\u\s[10]\h\s[23]北島。\w9さっきね、\w5%trainが%trainをぶちぬいてたよ。\w9\w9\uま、\w5たまには見るだろ。\e'
	'\u\s[-1]\h\s[21]エロイムエッサイム、\w5エロイムエッサイム〜。\w9\w9\u\s[51]…\w5…\w9なにやってんだ？\w9\h\s[22]\n\n[half]うわはっ！\w9\w9\s[23]\nああ。\w9見られた。\w9\w9\s[4]もう、\w5このおまじないは無効だ〜。\w9\w9\u\s[14]\n\n[half]なんのおまじないなんだよ。\e'
	'\u\s[10]\h\s[4]ぶえしっ！\w9\w9\u\s[13]なんだ風邪か？\w9うつすなよ？\w9\w9\h\s[27]\n\n[half]やさしさのかけらもないやつだなー。\w9\w9\u\s[39]\n\n[half]この間、\w5俺が風邪引いたときになんて言った？\h\s[0]\n\n[half]寄るなバイ菌。\w9\w9\u\s[19]\n\n[half]…\w5…\w9やさしいだろ？\w9俺。\e'
	'\u\s[10]\h\s[5]北島、\w5今日の給食の献立知ってる？\w9\w9\u\s[13]うーん、\w5なんだったかな。\w9\w9\h\s[26]\n\n[half]甘いね、\w5キミは。\w9\w9\s[20]\nこうだ！\w9\n\n[half]\_q%(lunch_main)\n%(lunch_dish)\n%(lunch_soup)\n%(lunch_dessert)\n%(lunch_drink)\_q\w9\w9\w9\w9\s[21]\n\n[half]えっへん。\w9\w9\u\s[14]\n\n[half]はいはい。\w9すげーすげー。\e'
	'\h\s[0]\u\s[13]そういや、\w5ここの実習のせいで、\w5\n最近は部活に出てないな。\w9\w9\hあんた、\w5何部だっけ？\w9\w9\u\s[10]\n\n[half]陸上だよ。\w9長距離やってる。\w9\w9\h\s[28]\n\n[half]なるほどね。\w9\nどうりでいつもぼーっとしてると思った。\w9\w9\u\s[17]\n\n[half]誰がぼーっとしてんだよ！\w9\nだいたい偏見だぞそれ。\e:chain=club01'
	'\u\s[10]\h\s[43]うっぐ…\w5…\w9ぐっ。\w9\w9\u\s[32]お、\w5おい、\w5なんだよ。\w9どうしたんだよ。\w9\w9\h\s[4]\n\n[half]ぶえくしょい。\w9\w9\s[3]\nまいったー。\w9くしゃみが止まんないよ。\w9\w9\u\s[50]\n\n[half]…\w5…\w9そうだよな。\w9バカだもんな、\w5こいつ。\w9\w9\h\s[7]\n\n[half]あー？\e'
}

ランダムトーク6月上旬 : array
	{
		'\u\s[10]\h\s[0]もうすぐプール開きだね。\w9\w9\uああ、\w5そうだな。\w9\w9\h\s[1]\n\n[half]やだな。\w9さぼろっかなー。\w9\w9\u\s[14]\n\n[half]またかよ。\w9だらけたやつだな。\w9\w9\h\s[40]\n\n[half]あんたみたいな連中が覗きにくるしさ。\u\s[17]\n\n[half]ふざけんなぼけ！\e'
	}

ランダムトーク6月中旬 : array
	{
		'\u\s[10]\h\s[0]もうすぐプール開きだね。\w9\w9\uああ、\w5そうだな。\w9\w9\h\s[1]\n\n[half]やだな。\w9さぼろっかなー。\w9\w9\u\s[14]\n\n[half]またかよ。\w9だらけたやつだな。\w9\w9\h\s[40]\n\n[half]あんたみたいな連中が覗きにくるしさ。\u\s[17]\n\n[half]ふざけんなぼけ！\e'
	}

ランダムトーク6月下旬 : array
	{
		'\u\s[10]\h\s[0]合唱コンクールが近いね。\w9\w9\u\s[13]俺、\w5歌は苦手なんだよな。\w9\w9\h\s[23]\n\n[half]最近、\w5声ががらついてるしね。\w9\w9\u\s[11]\n\n[half]ちっとな。\e'
		'\h\s[0]\u\s[10]そういやもうすぐ期末だな。\w9\n勉強やってるか？\w9\w9\h\s[20]ああ、\w5もうすぐったって７月じゃん。\w9\nまだまだ余裕だよ。\w9\w9\u\s[18]\n\n[half]あっという間だぜ。\e'
	}

ランダムトーク7月上旬 : array
	{
		'\u\s[10]\h\s[22]北島！\w9数学、\w5ここ教えて！\w9\w9\u\s[14]だからふだんから勉強しとけってあれほど。\w9\w9\h\s[27]\n\n[half]いま、\w5そんなこと言ってもしょうがないだろ！\w9\w9\s[5]\nほら、\w5ここ、\w5ここ。\w9\nここわかんない。\w9\w9\u\s[13]\n\n[half]…\w5…\w9これ、\w5小学校でやる部分じゃないか？\e'
	}

//---- チェイントーク ---------------------------------------------------------
kenka01
{{CHAIN
	{
		"\u\s[10]\h\s[9]とと…\w5…\w9ほら、\w5こういうのがよくないって。\w9\w9\u\s[11]ん。\w9ま、\w5そうだな。\w9反省するか。\e"
		"\h\s[0]\u\s[16]だいたいだな、\w5お前は根性が曲がりすぎてるんだよ。\w9\w9\h\s[8]あたし、\w5あんたみたいないい子ちゃんじゃないしねー。\w9\w9\u\s[17]\n\n[half]いい子ちゃんじゃねえ！\w9\w9\h\s[7]\n\n[half]どこが曲がってるってんだよ！\w9\w9\w9\w9\w9\s[4]\c\u\s[14]\c\_sはぁ。\_s\e:chain=end"
	}
	"\u\s[10]\h\s[6]…\w5…\w9よし、\w5反省終わり。\w9\w9\s[8]\n仲直りの印に、\w5宿題写させてよ。\w9\w9\u\s[13]…\w5…\w9はぁ？\e:chain=end"
	"\u\s[10]\h\s[0]で、\w5もう今後はケンカはやめね。\w9\w9\u\s[15]ん。\w9そうしようぜ。\w9\w9\h\s[5]\n\n[half]実はさ、\w5昨日借りたノートだけど〜。\w9\w9\u\s[19]\n\n[half]はは。\w9まだ写し終わってないんだろ？\w9\nいいよ、\w5明日で。\w9\w9\h\s[3]\n\n[half]いやね？\w9昨日は雨だったじゃん。\w9\n水たまりに落として二目と見れない姿に\u\s[17]\n\n[half]てめえなんかと仲良くできるか、\w5このどぶす！\w9\w9\h\s[7]\n\n[half]せっかくひとが謝ろうとしてるのになんだそりゃー！\e"
}}CHAIN*/

club01
{{CHAIN
	{
		"\h\s[0]\u\s[10]そういう井上は何部だった？\w9\w9\hあたし？\w9剣道。\w9\w9\u\s[18]\n\n[half]なるほどな。\w9粗暴なお前にぴったりだ。\w9\w9\h\s[7]\n\n[half]なんだとー！\w9あんたこそ偏見そのものじゃん！\e"
	}
	"\u\s[50]\h\s[40]\_sむ〜〜〜〜〜〜〜〜〜〜〜〜〜〜。\_s\w9\w9\u\s[14]\n\n[half]ま、\w5いいや。\w9\nお互い練習ができないとやばいよな。\w9\w9\h\s[23]\n\n[half]そうなんだよね。\w9\nあんたと違ってあたしは期待されてるし、\w5\nレギュラー目指してるし。\w9\w9\u\s[37]\n\n[half]だからこいつはもう…\w5…\w9。\e:chain=end"
}}CHAIN*/

//**** 時報/重なり **********************************************************************

//---- OnMinuteChangeイベント -----------------------------------------------------------
OnMinuteChange
{
	//---- 時間の分を見て 0 であれば時報。それ以外のときは重なり処理を行う

	if minute == 0
	{
		//---- 分 = 0 だったので時報
		"\1\s[10]%hour12時です。"
		--
		//---- 特定の時間（正午など）ではさらに追加で話す
		if hour == 12
		{
			"\n\n\u\s[10]\h\s[5]今日の給食はなんだ〜！？\w9\w9\u\s[13]こんなところで給食は出ねえよ。\w9\w9\h\s[4]\n\n[half]そ、\w5それだけを楽しみに午前中を生きてきたのに。\w9\w9\u\s[14]\n\n[half]いや、\w5飯は食ってもいいっての。"
		}
		elseif hour == 15
		{
			"\n\n\u\s[10]\h\s[3]…\w5…\w9ここ、\w5おやつ出ない？\w9\w9\u\s[19]遊び場じゃないんだけどな。"
		}
		--
		"\e"
	}
	elseif mikireflag == 1
	{
		//---- 分 != 0 、かつ見切れていたら見切れ中のトークを行う
		MikireTalk
	}
	elseif reference2 == 1
	{
		//---- 分 != 0 、かつ見切れておらず本体とkeroが重なっていたら重なり処理
		//---- 大抵はkero側を引き離す処理を行う
		"\u\s[10]\h\s[1]な、\w5なに？\w9\w9\u\s[12]わ、\4\w5悪い！\w9\w9\s[11]\e"
	}
}


//**** 見切れ ***************************************************************************

//---- OnSecondChangeイベント -----------------------------------------------------------
OnSecondChange
{
	//---- 1 秒毎に実行される。ここではあまり重い処理を行わないこと
	//---- このテンプレートでは、見切れ処理のみ行っている

	if mikireflag == 1 && reference1 == 0
	{
		//---- 見切れの終了
		EndMikireTalk
	}
	mikireflag = reference1
}

//---- 見切れ中 -------------------------------------------------------------------------
MikireTalk
{
	"\u\s[10]\h\s[1]見切れてるね。\w9じゃま？\w9\w9\uデスクトップの広さは有限だからな。\w9\w9\h\s[3]\n\n[half]んじゃ、\w5あんたどっか行ってよ。\w9\w9\u\s[17]\n\n[half]なんだよそりゃ！！\e"
}

//---- 見切れ終了 -----------------------------------------------------------------------
EndMikireTalk
{
	"\u\s[10]\h\s[4]あー。\w9落ち着く。\w9\w9\u\s[13]見切れはいやなもんだな。\e:chain=mikirego"
}

//---- 見切れ後の初回のランダムトークは見切れ関連のトークを行う。これをチェインで実現している ----
mikirego
{{CHAIN
	"\u\s[10]\h\s[8]やっぱ、\w5あんたいない方がいいんじゃない？\w9\w9\u\s[30]お前こそな。\w9\n\n[half]\w9\w9\w9\h\s[6]\n\n[half]\_s…\w5…\w5…\w5…\w5…\w5…\w9\_s\w9\w9\s[5]\u\s[15]\_sあ\w1は\w1は\w1は\w1は\w1は\w1は\w1は\w1は\w1は\w1は。\_s\w9\w9\h\s[7]\n\n[half]\u\s[17]\n\n[half]\hな\uう\hん\uる\hだ\uせ\hて\uー\hめ\u女\hー\uだ\h！\uな\_s！\_s\e"
}}CHAIN

//**** サーフィス復元 *******************************************************************

//---- OnSurfaceRestoreイベント ---------------------------------------------------------
OnSurfaceRestore
{
	"\0\s[0]\1\s[10]\e"
}