//=============================================================
// aya_tips.dic にコピペ
//=============================================================

//**** 好感度判定ロジック
//変数lpは直接代入しないこと

OnSystemLoad.TIPS_LP
{
	//好感度初期化
	if ISVAR('lp') == 0 {
		好感度初期化
	}
	if ISVAR('lp_downlock') == 0 {
		lp_downlock = 0
	}
}

//----------------------------------------------

好感度初期化
{
	//\0側
	lp[0] = 20
	
	//\1側
	lp[1] = 20
}

//----------------------------------------------

//GetLP() = 好感度0() か 好感度1()

好感度0
{
	好感度実処理部(0)
}

好感度1
{
	好感度実処理部(1)
}

好感度実処理部
{
	_lp = lp[_argv[0]];
	
	//50以上
	if _lp >= 50 {
		'好感'
	}
	//20以上50未満
	elseif (_lp >= 20) && (_lp < 50) {
		'通常'
	}
	//それ以外＝20未満
	else {
		'嫌'
	}
}

//----------------------------------------------

//書き方：好感度変更0(変更差分)
//ChangeLP(-1) = 好感度変更0(-1) か 好感度変更1(-1)

好感度変更0
{
	好感度変更実処理部(0,_argv[0])
}

好感度変更1
{
	好感度変更実処理部(1,_argv[0])
}

好感度変更実処理部
{
	_i = TOINT(_argv[1])
	_a = _argv[0]
	
	if _i < 0 {
		if lp_downlock == 0 {
			lp[_a] += _i //もともと負値なのでプラス演算で良いことに注意
		}
	}
	elseif _i > 0 {
		lp[_a] += _i
	}
}

//----------------------------------------------

好感度下げロック状態
{
	lp_downlock
}

好感度下げロック設定 : void
{
	if TOINT(_argv[0]) {
		lp_downlock = 1
	}
	else {
		lp_downlock = 0
	}
}

//=============================================================
// aya_lilith_config.dic の同じ名前の関数に上書き
//=============================================================

あやりりす・日付イベントユーザー定義
{
	_a = IARRAY
	
	_s = 好感度0()
	if _s == '好感' {
		_a ,= 'LP好感0'
		_a ,= 'LPTalk好感0'
		_a ,= 'LPTalk通常0'
	}
	elseif _s = '通常' {
		_a ,= 'LP通常0'
		_a ,= 'LPTalk通常0'
	}
	else {
		_a ,= 'LP嫌0'
		_a ,= 'LPTalk嫌0'
	}
	
	_s = 好感度1()
	if _s == '好感' {
		_a ,= 'LP好感1'
		_a ,= 'LPTalk好感1'
		_a ,= 'LPTalk通常1'
	}
	elseif _s = '通常' {
		_a ,= 'LP通常1'
		_a ,= 'LPTalk通常1'
	}
	else {
		_a ,= 'LP嫌1'
		_a ,= 'LPTalk嫌1'
	}
	
	_a
}